## tcsh completion
	complete vim	'n/*/f:^*.[oa]/'
	complete where	'n/*/c/'
	complete which	'n/*/c/'
	complete whereis	'n/*/c/'

	complete cd  	'p/1/d/'		# Directories only
	complete complete 	'p/1/X/'		# Completions only
	complete uncomplete	'n/*/X/'
	
	complete dd	'c/if=/f/' 'c/of=/f/' \
			'p/*/(bs cbs count files fillchar ibs if iseek obs of oseek seek skip conv)/=/'

	complete set	'c/*=/f/' 'p/1/s/=' 'n/=/f/'
	complete unset	'n/*/s/'
	complete alias 	'p/1/a/'		# only aliases are valid
	complete unalias	'n/*/a/'
	complete man	'p/*/c/'

	complete {fg,bg,stop}	'c/%/j/' 'p/1/"(%)"//'

	complete limit	'c/-/"(h)"/' 'n/*/l/'
	complete unlimit	'c/-/"(h)"/' 'n/*/l/'
	
	complete kill       'c/-/S/' 'c/%/j/' 'n/*/`ps -ax | awk '"'"'{print $1}'"'"'`/'
	complete killall    'c/-/S/' 'c/%/j/' 'n/*/`ps -axc | awk '"'"'{print $5}'"'"'`/'

	complete find 	'n/-fstype/"(nfs 4.2)"/' 'n/-name/f/' \
		  	'n/-type/"(c b d f p l s)"/' 'n/-user/u/ n/-group/g/' \
			'n/-exec/c/' 'n/-ok/c/' 'n/-cpio/f/' 'n/-ncpio/f/' 'n/-newer/f/' \
		  	c/-/"(fstype name perm prune type user nouser \
		  		 group nogroup size inum atime mtime ctime exec \
				 ok print ls cpio ncpio newer xdev depth \
				 daystart follow maxdepth mindepth noleaf version \
				 anewer cnewer amin cmin mmin true false uid gid \
				 ilname iname ipath iregex links lname empty path \
				 regex used xtype fprint fprint0 fprintf \
				 print0 printf not a and o or)"/ \
				 'n/*/d/'

	complete bunzip2	'p/*/f:*.bz2/' 
	complete bzip2	'n/-9/f:^*.bz2/' 'n/-d/f:*.bz2/'
	complete crontab	'n/-u/u/'
	complete camcontrol	'p/1/(cmd debug defects devlist eject inquiry \
			modepage negotiate periphlist rescan reset start \
			stop tags tur)/'

	complete edquota	'n/*/u/'

	complete ifconfig	'p@1@`ifconfig -l`@' 'n/*/(range phase link netmask \
			mtu vlandev vlan metric mediaopt down delete \
			broadcast arp debug)/'

	complete postfix	'p/*/(start stop reload abort flush check set-permissions upgrade-configuration/'
	complete postmap	'n/1/(hash: regexp:)' 'c/hash:/f/' 'c/regexp:/f/'

	complete mount	'c/-/(a r t v)/' \
			'n/-t/(cd9660 ext2fs fdescfs linprocfs \
			linsysfs mfs mqueuefs msdosfs nfs nfs4 ntfs nullfs nwfs \
			nwfs portalfs procfs pseudofs reiserfs smbfs udf umapfs unionfs xfs)/' 
#			'n@*@`grep -v "^#" /etc/fstab | tr -s " " "	" | cut -f 2`@'

	complete umount	'c/-/"(a h t v)"/ n/-t/"(4.2 nfs)"/' \
			'n/-h/`df | cut -s -d ":" -f 1 | sort -u`/' \
			'n/*/`mount | cut -d " " -f 3`/'


	complete su		c/--/"(login fast preserve-environment command shell \
			help version)"/	c/-/"(f l m p c s -)"/ \
			'n/{-c,--command}/c/' \
			'n@{-s,--shell}@`cat /etc/shells`@' 'n/*/u/'

	complete sed	c/--/"(quiet silent version help expression file)"/   \
			c/-/"(n V e f -)"/ n/{-e,--expression}/x:'<script>'/  \
			'n/{-f,--file}/f:*.sed/' 'N/-{e,f,-{file,expression}}/f/' \
			n/-/x:'<script>'/ N/-/f/ p/1/x:'<script>'/ 'p/2/f/'

	## FreeBSD specific completions
	
	complete sysctl	'n/*/`sysctl -Na`/'
	complete */rc.d/*	'p/1/(start stop reload restart status rcvar onestart onestop)/'
	complete service	'c/-/(e l r v)/' 'p/1/`service -l`/' 'n/*/(start stop reload restart status rcvar onestart onestop)/'
	complete kldload	'n@*@`ls -1 /boot/modules/ /boot/kernel/ | awk -F/ \$NF\ \~\ \".ko\"\ \{sub\(\/\.ko\/,\"\",\$NF\)\;print\ \$NF\}`@'
	complete kldunload	'n@*@`kldstat | awk \{sub\(\/\.ko\/,\"\",\$NF\)\;print\ \$NF\} | grep -v Name`@'

	complete gmirror    'p/1/(activate clear configure deactivate dump forget label insert rebuild remove stop help list status load unload)/' \
				'n/-b/(load prefer round-robin split)/' 'n/{activate,clear,deactivate,forget,insert,rebuild,remove,stop,unload}/(-v)/' \
				'n/{label}/(-b -F -h -n -s -v)/' \
				'n/{configure}/(-a -b -d -f -F -h -n -p -s -v)/'
	complete atacontrol 'p/1/(list info attach detach reinit create delete addspare rebuild status mode cap spindown)/' \
				'n@{detach,attach}@`atacontrol list | awk '"'"'$1 ~ /^ATA channel/ { printf("ata%d\n", $3) }'"'"'`@'

	complete jlogin 'p@1@`jls -v | awk '"'"'$2 ~ /ACTIVE/ { print $1 }'"'"'`@'

	set _PoRtS_InDeX_="/usr/ports/INDEX-`uname -r | cut -d . -f 1`"
	alias _PKGS_VeRsIoN_	'ls -1 /var/db/pkg'
	alias _PKGS_No_VeRsIoN_	'ls -1 /var/db/pkg | sed "s%/var/db/pkg/%%;s%^\(.*\)-[0-9].*%\1%"'
	alias _PKGS_AvAiLaBlE_	'awk -F\| \{sub\(/-\[0-9\]\.\*\/\,\"\"\,\$1\)\;print\ \$1\} /usr/ports/INDEX-`uname -r | cut -d . -f 1` | sort -u'
	alias _PKGS_PkGs_PoRtS_	'awk -F\| \{sub\(\"\/usr\/ports\/\"\,\"\"\,\$2\)\;print\ \$2\} /usr/ports/INDEX-`uname -r | cut -d . -f 1` && pkg_info -E \*'

	complete portupgrade	'c/--/(help all afterinstall= backup-packages beforebuild= clean cleanup \
				distclean force fetch-only ignore-moved interactive keep-going results-file= \
				log-file= make-args= make-env= noexecute new origin= omit-check package \
				use-packages use-packages-only noconfig recursive upward-recursive sudo \
				sudo-command= uninstall-shlibs verbose noclean nocleanup exclude= yes)/' \
				'c/-/(h a A b B c C D f F i k l L m M n N o O p P q r R s S u v w W x y)/' \
				'n@*@`_PKGS_VeRsIoN_`@'

	complete portversion	'n@*@`_PKGS_VeRsIoN_`@'
	complete pkg_deinstall	'n@*@`_PKGS_VeRsIoN_`@'
	complete pkg_info	'c/-/(a b v p q Q c d D f g i I j k K r R m L s o G W O x X e E l t V P)/' \
				'n@*@`_PKGS_VeRsIoN_`@'
	complete pkg_delete	'c/-/(a d D f G i n p r v x X)/' \
				'n@*@`_PKGS_VeRsIoN_`@'
	complete pkg_tree	'c/-/(b q t v)/' \
				'n@*@`_PKGS_VeRsIoN_`@'


	complete portinstall 'n@*@`_PKGS_AvAiLaBlE_`@'
	complete pkg_add 'n@-r@`_PKGS_AvAiLaBlE_`@'
	complete portell 'n@*@`_PKGS_AvAiLaBlE_`@'

	complete portmaster	'c/--/(always-fetch check-depends check-port-dbdir clean-distfiles \
				clean-packages delete-build-only delete-packages force-config help \
				index index-first index-only list-origins local-packagedir no-confirm \
				no-index-fetch no-term-title packages packages-build packages-if-newer \
				packages-local packages-only show-work update-if-newer version)/' \
				'c/-/(a b B C d D e f F g G h H i l L m n o p r R s t u v w x)/' \
				'n@*@`_PKGS_PkGs_PoRtS_`@'
#				'n@*@`_PKGS_VeRsIoN_`@'

#	complete {portupgrade,pkg_delete,pkg_info}	'c/-/"(f x)"/p@*@D:/var/db/pkg@@'
	
	complete portsnap	'c/-/(I d f k p s)/' \
			'n/-d/d/' \
			'n/-p/d/' \
			'n/*/(fetch extract update)/'

	complete make	'n/*/(config config-recursive fetch checksum depends extract patch configure build install showconfig \
				showconfig-recursive rmconfig rmconfig-recursive config-conditional fetch-list \
				fetch-recursive fetch-recursive-list pretty-print-run-depends-list \
				pretty-print-build-depends-list clean distclean deinstall deinstall-all package \
				package-recursive readmes search describe index fetchindex quicksearch)/' \
		'c@name=@`awk -F\| \{sub\(/-\[0-9\]\.\*\/\,\"\"\,\$1\)\;print\ \$1\} $_PoRtS_InDeX_ | sort -u`@'
#		'c@name=@`awk -F\| \{sub\(/-\[0-9\]\.\*\/\,\"\"\,\$1\)\;print\ \$1\} /usr/ports/INDEX-8 | sort -u`@'